Функция _Date_Time

Функция _Date_Time_SetSystemTime

_Date_Time_SetSystemTime

Устанавливает текущую системную дату и время, выраженные в UTC

#include <Date.au3>
_Date_Time_SetSystemTime($pSystemTime)

Параметры

$pSystemTime

Указатель на структуру $tagSYSTEMTIME, которая содержит новую системную дату и время

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False

Примечания

Функция SetLocalTime применяет привилегию SE_SYSTEMTIME_NAME перед изменением локального времени

См. также

_Date_Time_GetSystemTime, $tagSYSTEMTIME

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; Под Vist-ой Windows API "SetSystemTime" может не выполняться из-за параметров безопасности

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $tCur, $tNew

; Создаёт GUI
$hGUI = GUICreate("Время", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Получение текущего системного времени
$tCur = _Date_Time_GetSystemTime()
MemoWrite("Текущее системное время    .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

; Устанавливает новое системное время
$tNew = _Date_Time_EncodeSystemTime(8, 19, @YEAR, 3, 10, 45)
If Not _Date_Time_SetSystemTime(DllStructGetPtr($tNew)) Then
MsgBox(4096, "Ошибка", "Системное время не может быть установлено" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
Exit
EndIf
$tNew = _Date_Time_GetSystemTime()
MemoWrite("Новые системные дата/время .: " & _Date_Time_SystemTimeToDateTimeStr($tNew))

; Восстановление системного времени
_Date_Time_SetSystemTime(DllStructGetPtr($tCur))

; Получение текущего системного времени
$tCur = _Date_Time_GetSystemTime()
MemoWrite("Текущее системное время    .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite