Функция _Date_Time_GetSystemTimes

         Описание функции

_Date_Time_GetSystemTimes

Возвращает информацию о системном времени

#include <Date.au3>
_Date_Time_GetSystemTimes()

Возвращаемое значение

Возвращает массив следующего формата:
    [0] - структура $tagFILETIME с общим временем простоя системы
    [1] - структура $tagFILETIME с общим временем системы в режиме ядра
    [2] - структура $tagFILETIME с общим временем работы пользователя в системе

Примечания

Минимальная ОС - Windows XP/SP1, 2003

См. также

$tagFILETIME

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $aTime

    ; Создаёт GUI
    $hGUI = GUICreate("Время", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Получение системного времени
    $aTime = _Date_Time_GetSystemTimes()

    MemoWrite("Время простоя                 .: " & _Date_Time_FileTimeToStr($aTime[0]))
    MemoWrite("Время системы в режиме ядра   .: " & _Date_Time_FileTimeToStr($aTime[1]))
    MemoWrite("Работы пользователя в системе .: " & _Date_Time_FileTimeToStr($aTime[2]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite