Функция _Date_Time_FileTimeToArray

         Описание функции

_Date_Time_FileTimeToArray

Декодирует время файла в массив

#include <Date.au3>
_Date_Time_FileTimeToArray(ByRef $tFileTime)

Параметры

$tFileTime Структура $tagFILETIME

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Месяц
        [1] - День
        [2] - Год
        [3] - Час
        [4] - Минуты
        [5] - Секунды
        [6] - Миллисекунды
        [7] - День недели

См. также

$tagFILETIME

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $tFile, $aFile, $sFile

    ; Создаёт GUI
    $hGUI = GUICreate("Время", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Кодирует файловое время
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $aFile = _Date_Time_FileTimeToArray($tFile)
    $sFile = StringFormat("%02d/%02d/%04d %02d:%02d:%02d", $aFile[0], $aFile[1], $aFile[2], $aFile[3], $aFile[4], $aFile[5])
    MemoWrite("Текущие дата/время .: " & $sFile)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite