Функция _Crypt

Функция _Crypt_DeriveKey

_Crypt_DeriveKey

Создает ключ от алгоритма и пароля

#include <Crypt.au3>
_Crypt_DeriveKey($vPassword, $iALG_ID [, $iHash_ALG_ID = $CALG_MD5])

Параметры

$vPassword	Пароль
$iALG_ID	Алгоритм шифрования используемый с ключом
$iHash_ALG_ID	[необязательный] Алгоритм для хеша пароля

Возвращаемое значение

Успех:	Возвращает указатель криптографического ключа,
	Устанавливает @error = 0
Ошибка:	Возвращает -1 и устанавливает @error:
	1 - Не удалось создать хеш объект
	2 - Не удалось создать хеш пароля
	3 - Не удалось создать ключ

Примечания

Ключ требуется уничтожить функцией _Crypt_DestroyKey.
Алгоритм AES не доступен на Windows 2000.

См. также

_Crypt_DestroyKey, _Crypt_EncryptData, _Crypt_EncryptFile, _Crypt_DecryptData, _Crypt_DecryptFile

См. также

Искать CryptDeriveKey в библиотеке MSDN

Пример

#include <Crypt.au3>

Local $aStringsToEncrypt[6] = ["AutoIt", "SciTE", "Crypt", ".au3", 42, "42"]
Local $sOutput = ""

Local $hKey = _Crypt_DeriveKey("CryptPassword", $CALG_RC4) ; Declare a password string and algorithm to create a cryptographic key.

For $iWord In $aStringsToEncrypt
$sOutput &= $iWord & @TAB & " = " & _Crypt_EncryptData($iWord, $hKey, $CALG_USERKEY) & @CRLF ; Encrypt the text with the cryptographic key.
Next

MsgBox(4096, "Encrypted data", $sOutput)

_Crypt_DestroyKey($hKey) ; Destroy the cryptographic key.