Функция TrayItemSetText

         Описание функции

TrayItemSetText

Устанавливает текст элемента меню или пункта трея.

TrayItemSetText ( controlID, text )

Параметры

controlID Идентификатор элемента (controlID), возвращаемый функциями TrayCreateItem() или TrayCreateMenu().
text Новый текст для элемента меню или пункта трея.

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

Примечания

Чтобы изменить текст пунктов по умолчанию ("Script Paused" и "Exit") используйте константы $TRAY_ITEM_EXIT и $TRAY_ITEM_PAUSE в качестве controlID.

См. также

TrayItemGetText, TrayCreateItem, TrayCreateMenu

Пример

#include <Constants.au3> ; Необходимо для констант $TRAY_ITEM_EXIT and $TRAY_ITEM_PAUSE.
#NoTrayIcon

Opt("TrayAutoPause", 0) ; Скрипт не приостанавливается при клике на иконке в трее.
Opt("TrayMenuMode", 2) ; Не отмечать галочками при выборе пунктов.

$iRandom = TrayCreateItem("Изменяет текст")
TrayCreateItem("") ; Создаёт разделитель
$iAbout = TrayCreateItem("О программе")

TraySetState() ; Показывает меню трея
; Устанавливает текст пункту
Sleep(100)

While 1
    Switch TrayGetMsg()
        Case 0
            ContinueLoop
        Case $iRandom
            $tmp = Int(Random(1, 10, 1))
            TrayItemSetText($iRandom, "Изменяет текст - " & $tmp)
            TrayItemSetText($TRAY_ITEM_EXIT, "Завершить программу - " & $tmp)
            TrayItemSetText($TRAY_ITEM_PAUSE, "Приостановить программу - " & $tmp)
        Case $iAbout
            MsgBox(64, "О программе:", "Пример установки числа")
    EndSwitch
WEnd