Функция TrayItemSetOnEvent

TrayItemSetOnEvent

Назначает пользовательскую функцию, вызываемую при клике пункта в меню трея.

TrayItemSetOnEvent ( itemID, "function" )

Параметры

itemID	Идентификатор пункта (itemID), возвращаемый функцией TrayCreateItem().
function	Имя вызываемой пользовательской функции.

Возвращаемое значение

Успех:	Возвращает 1.
Ошибка:	Возвращает 0.
@error:	1, если "функция" не определена.

Примечания

Функции OnEvent вызываются только при включенной опции TrayOnEventMode установленной в 1, при использовании этого режима TrayGetMsg() не используется.

В пределах вызываемой пользовательской функции идентификатор пункта можно извлечь из @TRAY_ID.

Если вместо имени функции указана пустая строка "" , то предыдущая функция становится отключенной от элемента управления.

См. также

TrayCreateItem, TrayGetMsg, TrayOnEventMode (Опция), TraySetOnEvent

Пример

#NoTrayIcon

Opt("TrayMenuMode", 1 + 2) ; Не отображать в трее пункты меню по умолчанию (Script Paused/Exit) и не отмечать галочками при выборе.
Opt("TrayOnEventMode", 1) ; Включает режим TrayOnEventMode.

TrayCreateItem("Информация")
TrayItemSetOnEvent(-1, "_Info")

TrayCreateItem("") ; Создаёт разделитель

TrayCreateItem("Выход")
TrayItemSetOnEvent(-1, "_Exit")

TraySetState(1) ; Показывает меню трея

While 1
Sleep(1000) ; Бездействующий цикл
WEnd

Func _Info()
MsgBox(4096, "Информация", "Демонстрация режима OnEvent для трея")
EndFunc

Func _Exit()
Exit
EndFunc