Функция GUIGetStyle

         Описание функции

GUIGetStyle

Извлекает стили окна GUI.

GUIGetStyle ( [ winhandle ] )

Параметры

winhandle [необязательный] Дескриптор окна, возвращённый функцией GUICreate() (по умолчанию предыдущее используемое окно).

Возвращаемое значение

Успех:Возвращает два элемента массива, содержащего информацию о стилях:
$array[0] = Стиль
$array[1] = Расширенный стиль
Ошибка:Возвращает 0.

Примечания

Будьте внимательны к изменению стиля после использования функции GUISetState().

См. также

GUICreate, GUISetStyle

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $bToggle = False, $hGui, $iBtnStyle, $aGuiStyles, $Msg

    $hGui = GUICreate("Стили Gui", 260, 100)
    $iBtnStyle = GUICtrlCreateButton("Установить стиль", 45, 50, 150, 28)

    $aGuiStyles = GUIGetStyle($hGui) ; будьте внимательны, при изменении стиля после создания окна

    GUISetState()

    While 1
        $Msg = GUIGetMsg()
        Switch $Msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $iBtnStyle
                $bToggle = Not $bToggle
                If $bToggle Then
                    GUISetStyle(BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), BitOR($WS_EX_CLIENTEDGE, $WS_EX_TOOLWINDOW))
                    GUICtrlSetData($iBtnStyle, 'Восстановить стиль')
                Else
                    GUISetStyle($aGuiStyles[0], $aGuiStyles[1])
                    GUICtrlSetData($iBtnStyle, 'Установить стиль')
                EndIf
            Case Else
        EndSwitch
    WEnd
EndFunc