Функция GUICtrlSendToDummy

         Описание функции

GUICtrlSendToDummy

Посылает сообщения элементу Dummy.

GUICtrlSendToDummy ( controlID [, state ] )

Параметры

controlID Идентификатор элемента возвращаемый функцией GUICtrlCreateDummy()
state [необязательный] Значение, которое может быть прочитано позже, функцией GUICtrlRead()

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

Примечания

Когда эта функция вызывает уведомление, оно может быть захвачено функцией GUIGetMsg() или GUICtrlSetOnEvent(), как если бы элемент был кликнут нажатием.

См. также

GUICtrlCreateDummy, GUICtrlSetOnEvent, GUICtrlRead

Пример

#include <GUIConstantsEx.au3>

Global $iUserDummy

Example()

Func Example()
    Opt("GUIOnEventMode", 1) ; режим OnEvent

    GUICreate("GUISendToDummy", 220, 200, 100, 200)
    ; GUISetBkColor(0x00E0FFFF) ; Изменяет цвет фона GUI.
    GUISetOnEvent($GUI_EVENT_CLOSE, "OnClick") ; Устанавливает вызов функции 'OnClick' при клике на кнопке закрытия GUI.

    $iUserDummy = GUICtrlCreateDummy()
    GUICtrlSetOnEvent(-1, "OnExit") ; Устанавливает вызов функции 'OnExit' при взаимодействии с этим элементом.

    GUICtrlCreateButton("Закрыть", 70, 170, 85, 25)
    GUICtrlSetOnEvent(-1, "OnClick") ; Устанавливает вызов функции 'OnClick' при взаимодействии с этим элементом.

    ; Показывает GUI.
    GUISetState()

    While 1
        Sleep(100)
    WEnd
EndFunc

Func OnClick()
    Return GUICtrlSendToDummy($iUserDummy) ; кликает элемент пустышки (Dummy)
EndFunc

Func OnExit()
    ; здесь можно добавить какое либо действие перед завершением программы
    Exit ; Завершает выполнение скрипта.
EndFunc