Функция FileGetAttrib

FileGetAttrib

Возвращает строку, соответствующую атрибутам указанного файла/каталога.

FileGetAttrib ( "filename" )

Параметры

filename

Имя файла (или каталога) для проверки.

Возвращаемое значение

Успех:	Возвращает строку, соответствующую атрибутам указанного файла/каталога.
Ошибка:	Возвращает "" (пустую строку) и устанавливает значение @error равным 1.

Примечания

Возвращённая строка, содержит комбинацию из символов "RASHNDOCT", означающих:
"R" = READONLY (только для чтения)
"A" = ARCHIVE (архивный)
"S" = SYSTEM (системный)
"H" = HIDDEN (скрытый)
"N" = NORMAL (нормальный)
"D" = DIRECTORY (каталог)
"O" = OFFLINE (оффлайн???)
"C" = COMPRESSED (сжатый, имеется в виду сжатие NTFS, а не ZIP)
"T" = TEMPORARY (временный)

См. также

FileSetAttrib, FileGetTime, FileExists, FileGetSize, FileSetTime

Пример

$sAttribute = FileGetAttrib("c:\boot.ini")
If @error Then
MsgBox(4096, "Ошибка", "Невозможно получить атрибуты файла.")
Exit
Else
If StringInStr($sAttribute, "R") Then
MsgBox(4096, "", "Файл только для чтения.")
EndIf
EndIf

; Отображает полную информацию атрибута в текстовой форме
; Создание двух массивов, в котором индексы позиции полного и сокращённого имени атрибута совпадают
$aInput = StringSplit("RASHNDOCT", '')
; $aOutput = StringSplit("Read-only,Archive,System,Hidden," & _ ; англ. названия
; "Normal,Directory,Offline,Compressed,Temporary", ",")
$aOutput = StringSplit("Только чтение,Архивный,Системный,Скрытый," & _
"Нормальный,Папка,Оффлайн,Сжатый,Временный", ",")
For $i = 1 To 9
$sAttribute = StringReplace($sAttribute, $aInput[$i], $aOutput[$i] & ' / ', 0, 1) ; замена сокращённого на полное имя атрибута
; последний параметр в функции StringReplace означает "учитывать регистр букв"
Next
$sAttribute = StringTrimRight($sAttribute, 3) ; удаляет разделительный слеш и пробел в конце строки
MsgBox(0, "Полные атрибуты файла:", $sAttribute)