VectorSourceLinearGradient()

Синтаксис

VectorSourceLinearGradient(x1.d , y1.d , x2.d , y2.d)

Описание

Выбирает линейный градиент цвета в качестве источника рисования для операций Векторной графики, таких как FillPath() или StrokePath(). Изначально градиент является сплошным и черным. После этой функции необходимо добавить цветовые опорные точки с помощью VectorSourceGradientColor().

Параметры

x1.d, y1.d	Задаёт точку, которая представляет собой начало (Позиция 0.0) градиента. Координаты задаются в системе координат источника #PB_Coordinate_Source.
x2.d, y2.d	Задаёт точку, которая представляет собой конец (Положение 1.0) градиента. Координаты задаются в системе координат источника #PB_Coordinate_Source.

Возвращаемое значение

Ничего.

Комментарии

См. обзор VectorDrawing для ознакомления с различными системами координат.

Градиент цвета задаётся только в области между точками (x1, y1) и (x2, y2). Вне этих точек цвет используемого источника зависит от операционной системы, поэтому следует избегать операций рисования вне области заданного градиента.

Пример

If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))

        VectorSourceLinearGradient(50, 0, 350, 0)
        VectorSourceGradientColor(RGBA(255, 0, 0, 255), 0.0)
        VectorSourceGradientColor(RGBA(0, 255, 0, 255), 0.5)
        VectorSourceGradientColor(RGBA(0, 0, 255, 255), 1.0)

        AddPathBox(50, 25, 300, 150)
        FillPath()

        StopVectorDrawing()
    EndIf

    Repeat
        Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
EndIf

См. также

VectorSourceGradientColor(), VectorSourceCircularGradient(), VectorSourceColor(), VectorSourceImage()

Поддерживаемые OS

Все