Функция _GDIPlus_PathAddEllipse

         Описание функции


_GDIPlus_PathAddEllipse

Добавляет эллипс в текущий объект GraphicsPath

#Include <GDIP.au3>
_GDIPlus_PathAddEllipse($hPath, $nX, $nY, $nWidth, $nHeight)

Параметры

$hPath Указатель на объект GraphicsPath
$nX X-координата левого верхнего угла прямоугольника, который ограничивает эллипс
$nY Y-координата левого верхнего угла прямоугольника, который ограничивает эллипс
$nWidth Ширина прямоугольника, который ограничивает эллипс
$nHeight Высота прямоугольника, который ограничивает эллипс

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки.

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hPath

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("Рисует объект GraphicsPath", 400, 200)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Задействует сглаживание
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)

    ; Создаёт объект GraphicsPath и добавляет эллипс
    $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 380, 180)

    ; Рисует путь
    _GDIPlus_GraphicsDrawPath($hGraphics, $hPath)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc