Функция _GDIPlus_GraphicsDrawPath

_GDIPlus_GraphicsDrawPath

Рисует последовательность линий и кривых, определяемых объектом GraphicsPath

#Include <GDIP.au3>
_GDIPlus_GraphicsDrawPath($hGraphics, $hPath[, $hPen = 0])

Параметры

$hGraphics	Указатель на объект Graphics
$hPath	Указатель на объект GraphicsPath, определяемый последовательность прямых и кривых линий, которые составляют путь
$hPen	[необязательный] Дескриптор объекта карандаша, который используется для рисования замкнутой кривой. Если 0, то сплошная чёрная линия шириной 1 пиксель.

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False, либо:
	Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
	$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
Local $hGUI, $hGraphics, $hPath

; Инициализирует библиотеку GDI+
_GDIPlus_Startup()

$hGUI = GUICreate("Рисует объект GraphicsPath", 400, 200)
GUISetState()

; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

; Задействует сглаживание
_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)

; Создаёт объект GraphicsPath и добавляет эллипс
$hPath = _GDIPlus_PathCreate()
_GDIPlus_PathAddEllipse($hPath, 10, 10, 380, 180)

; Рисует путь
_GDIPlus_GraphicsDrawPath($hGraphics, $hPath)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Освобождает ресурсы
_GDIPlus_PathDispose($hPath)
_GDIPlus_GraphicsDispose($hGraphics)

; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc