Функция _GDIPlus_LineBrushSetColors

_GDIPlus_LineBrushSetColors

Устанавливает начальный и конечный цвета объекта кисти линейного градиента

#Include <GDIP.au3>
_GDIPlus_LineBrushSetColors($hLineGradientBrush, $iARGBStart, $iARGBEnd)

Параметры

$hLineGradientBrush	Указатель на объект LinearGradientBrush
$iARGBStart	Цвет начала градиента (альфа-канал, красный, зелёный, синий)
$iARGBEnd	Цвет конца градиента (альфа-канал, красный, зелёный, синий)

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False, либо:
	Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
	$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

_GDIPlus_LineBrushGetColors

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
Local $hGUI, $hGraphics, $hBrush

; Инициализирует библиотеку GDI+
_GDIPlus_Startup()

$hGUI = GUICreate("_GDIPlus_LineBrushSetColors", 420, 200)
GUISetState()

; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

; Создаёт кисть линейного градиента, который плавно изменяет цвет с красного на зеленый
$hBrush = _GDIPlus_LineBrushCreate(0, 0, 0, 100, 0xFFFF0000, 0xFF009900, 1) ; Повторение кисти

; Заполняет прямоугольник кистью с линейным градиентом с красным и зеленым цветами
_GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 200, 200, $hBrush)

; Устанавливает начальный и конечный цвета объекта кисти линейного градиента в чёрный и белый
_GDIPlus_LineBrushSetColors($hBrush, 0xFF000000, 0xFFFFFFFF)

; Заполняет прямоугольник кистью с линейным градиентом с чёрным и белым цветами
_GDIPlus_GraphicsFillRect($hGraphics, 220, 0, 200, 200, $hBrush)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Освобождает ресурсы
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphics)

; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc