Функция _GDIPlus_LineBrushGetColors

         Описание функции


_GDIPlus_LineBrushGetColors

Возвращает начальный и конечный цвета объекта кисти линейного градиента

#Include <GDIP.au3>
_GDIPlus_LineBrushGetColors($hLineGradientBrush)

Параметры

$hLineGradientBrush Указатель на объект LinearGradientBrush

Возвращаемое значение

Успех:Возвращает массив, содержащий начальный и конечный цвета объекта LinearGradientBrush:
[0] - Начальный цвет
[1] - Конечный цвет
Ошибка:Возвращает -1, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

_GDIPlus_LineBrushSetColors

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hBrush

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("Получает цвета градиента", 420, 200)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Создаёт кисть линейного градиента, который плавно изменяет цвет с красного на зеленый
    $hBrush = _GDIPlus_LineBrushCreate(0, 0, 0, 100, 0xFFFF0000, 0xFF009900, 1) ; Повторение кисти

    ; Заполняет прямоугольник кистью с линейным градиентом с красным и зеленым цветами
    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 200, 200, $hBrush)

    ; Получает начальный и конечный цвета объекта кисти линейного градиента
    $aiColor = _GDIPlus_LineBrushGetColors($hBrush)
    If $aiColor <> -1 Then MsgBox(0, 'Цвета градиента', Hex($aiColor[0], 8) & @LF & Hex($aiColor[1], 8))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc