_GUICtrlStatusBar_GetRect
Возвращает ограничивающий прямоугольник части
#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRect($hWnd, $iPart)
Параметры
| $hWnd | Дескриптор элемента |
| $iPart |
Индекс части, отсчёт от 0 |
Возвращаемое значение
| Успех: | Возвращает массив следующего формата: |
| $aRect[0] = X-координата левого верхнего угла прямоугольника | |
| $aRect[1] = Y-координата левого верхнего угла прямоугольника | |
| $aRect[2] = X-координата правого нижнего угла прямоугольника | |
| $aRect[3] = Y-координата правого нижнего угла прямоугольника | |
| Ошибка: | Устанавливает @error |
См. также
_GUICtrlStatusBar_GetRectExПример
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
$Debug_SB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $aRect, $hStatus
Local $aParts[3] = [75, 150, -1]
; Создаёт GUI
$hGUI = GUICreate("StatusBar - Получает прямоугольник", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Устанавливает и получает части
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; Получает прямоугольник 1-ой части
$aRect = _GUICtrlStatusBar_GetRect ($hStatus, 0)
MemoWrite("Часть 1 слева ...: " & $aRect[0])
MemoWrite("Часть 1 сверху ..: " & $aRect[1])
MemoWrite("Часть 1 справа ..: " & $aRect[2])
MemoWrite("Часть 1 снизу ...: " & $aRect[3])
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite