Функция GUICtrlSetFont

         Описание функции


GUICtrlSetFont

Устанавливает шрифт элемента.

GUICtrlSetFont ( controlID, size [, weight [, attribute [, fontname [, quality ]]]] )

Параметры

controlID Идентификатор элемента возвращаемый функцией GUICtrlCreate....
size Размер шрифта (по умолчанию 8.5).
weight [необязательный] Толщина шрифта (400 = (по умолчанию) нормальный, 700 = жирный).
attribute [необязательный] Стиль:
2 - курсив
4 - подчёркнутый
8 - зачёркнутый
(объединение стилей: 2+4 = курсив и подчёркнутый).
fontname [необязательный] Имя шрифта.
quality [необязательный] Сглаживание шрифта
0 - Внешний вид шрифта не имеет значения (DEFAULT_QUALITY)
1 - Внешний вид шрифта менее важен, чем 2 (DRAFT_QUALITY)
2 - (по умолчанию) PROOF_QUALITY
3 - Сглаживание отключено (NONANTIALIASED_QUALITY)
4 - Сглаживание включено, если поддерживается шрифтом и он не слишком мелкий или крупный (ANTIALIASED_QUALITY)
5 - Сглаживание ClearType (CLEARTYPE_QUALITY)

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

Примечания

По умолчанию, шрифт элементов устанавливается функцией GUISetFont.

Размер шрифта может содержать десятичные доли, например 8.5.

Для некоторых элементов, как например Label, по умолчанию может быть 8.5 вместо 9 в соответствии с величинами темы Windows.

Смотрите Приложение полного списка шрифтов Windows и версий Windows, в которых они поддерживаются.

Для параметров Сглаживания проверьте MSDN, некоторые установки windows XP требуют CLEARTYPE_QUALITY=5

См. также

GUICtrlCreate..., GUISetFont

Пример

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $font, $msg

    GUICreate("Шрифт элемента") ; Создаёт окно в центре экрана

    $font = "Comic Sans MS"
    GUICtrlCreateLabel("Подчёркнутый", 10, 20, 110)
    GUICtrlSetFont(-1, 9, 400, 4, $font) ; отображает подчёркнутые символы

    GUICtrlCreateLabel("Курсив", 10, 40)
    GUICtrlSetFont(-1, 9, 400, 2, $font) ; отображает текст курсивом

    GUICtrlCreateLabel("Зачёркнутый", 10, 60)
    GUICtrlSetFont(-1, 9, 400, 8, $font) ; отображает зачёркнутые символы

    GUICtrlCreateLabel("Жирный", 10, 80)
    GUICtrlSetFont(-1, 9, 700, 0, $font) ; Жирный шрифт

    GUICtrlCreateLabel("Крупный", 10, 100, 110, 30)
    GUICtrlSetFont(-1, 16, 400, 0, $font) ; Крупный шрифт

    GUISetState() ; показывает созданное окно

    ; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case -3
                ExitLoop
        EndSwitch
    WEnd
EndFunc