Функция _GUICtrlHeader_SetItemOrder

         Описание функции

_GUICtrlHeader_SetItemOrder

Устанавливает порядковую позицию, в которой пункт появляется

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemOrder($hWnd, $iIndex, $iOrder)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0
$iOrder Порядковая позиция пункта, отсчёт от 0

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlHeader_GetItemOrder

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hHeader, $iMemo

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    _GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет колонки
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

    ; Устанавливает порядковую позицию колонки
    _GUICtrlHeader_SetItemOrder ($hHeader, 0, 3)

    ; Показывает порядковую позицию 1-ой колонки
    GUICtrlSetData($iMemo, "Порядковая позиция колонки с индексом 0: " & _GUICtrlHeader_GetItemOrder ($hHeader, 0))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main