Описание функции

_GUICtrlDTP_SetRangeEx

Устанавливает текущие минимальное и максимальное допустимое системное время

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetRangeEx($hWnd, ByRef $tRange)

Параметры

Возвращаемое значение

См. также

Пример

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo, $tRange

_Main()

Func _Main()
    Local $hDTP

    ; Создаёт GUI
    GUICreate("Устанавливает диапазон дат", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Устанавливает формат строки
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Устанавливает диапазон дат
    $tRange = DllStructCreate($tagDTPRANGE)
    DllStructSetData($tRange, "MinValid", True)
    DllStructSetData($tRange, "MinYear", @YEAR)
    DllStructSetData($tRange, "MinMonth", 1)
    DllStructSetData($tRange, "MinDay", 1)
    DllStructSetData($tRange, "MaxValid", True)
    DllStructSetData($tRange, "MaxYear", @YEAR)
    DllStructSetData($tRange, "MaxMonth", 12)
    DllStructSetData($tRange, "MaxDay", 31)
    DllStructSetData($tRange, "MaxHour", 12)
    DllStructSetData($tRange, "MaxMinute", 59)
    DllStructSetData($tRange, "MaxSecond", 59)
    _GUICtrlDTP_SetRangeEx($hDTP, $tRange)

    ; Отображает диапазон дат
    $tRange = _GUICtrlDTP_GetRangeEx($hDTP)
    MemoWrite("Минимальная дата..: " & GetDateStr("Min"))
    MemoWrite("Максимальная дата.: " & GetDateStr("Max"))
    MemoWrite("Минимальная время.: " & GetTimeStr("Min"))
    MemoWrite("Максимальная время: " & GetTimeStr("Max"))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Возвращает элементы даты
Func GetDateStr($sPrefix)
    If $sPrefix = "Min" Then
        Return StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MinMonth"), DllStructGetData($tRange, "MinDay"), DllStructGetData($tRange, "MinYear"))
    Else
        Return StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MaxMonth"), DllStructGetData($tRange, "MaxDay"), DllStructGetData($tRange, "MaxYear"))
    EndIf
EndFunc   ;==>GetDateStr

; Возвращает элементы времени
Func GetTimeStr($sPrefix)
    If $sPrefix = "Min" Then
        Return StringFormat("%02d:%02d:%02d", DllStructGetData($tRange, "MinHour"), DllStructGetData($tRange, "MinMinute"), DllStructGetData($tRange, "MinSecond"))
    Else
        Return StringFormat("%02d:%02d:%02d", DllStructGetData($tRange, "MaxHour"), DllStructGetData($tRange, "MaxMinute"), DllStructGetData($tRange, "MaxSecond"))
    EndIf
EndFunc   ;==>GetTimeStr

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite