Функция _GUICtrlComboBox

Функция _GUICtrlComboBox_ShowDropDown

_GUICtrlComboBox_ShowDropDown

Развернуть или свернуть список ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_ShowDropDown($hWnd [, $fShow = False])

Параметры

$hWnd	Дескриптор или идентификатор элемента
$fShow	[необязательный] Определяет, будет ли раскрывающийся список показан или скрыт: True - Показать список False - Скрыть список (по умолчанию)

Примечания

Эта функция не имеет эффекта для ComboBox созданного со стилем $CBS_SIMPLE.

См. также

_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_GetDroppedState

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hCombo

; Создаёт GUI
GUICreate("Развернуть или свернуть список", 400, 296)
$hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Добавляет файлы
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($hCombo)

; Получает состояние раскрытости списка
MemoWrite("Состояния раскрытости списка: " & _GUICtrlComboBox_GetDroppedState($hCombo))

Sleep(500)

; Раскрывает список
_GUICtrlComboBox_ShowDropDown($hCombo, True)

Sleep(500)

; Получает состояние раскрытости списка
MemoWrite("Состояния раскрытости списка: " & _GUICtrlComboBox_GetDroppedState($hCombo))

Sleep(500)

; Сворачивает раскрытый список
_GUICtrlComboBox_ShowDropDown($hCombo)

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite