Функция _GUICtrlComboBox_SetEditSel

         Описание функции

_GUICtrlComboBox_SetEditSel

Выделяет символы в поле ввода ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetEditSel($hWnd, $iStart, $iStop)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iStart Позиция начального символа
$iStop Позиция конечного символа

Возвращаемое значение

Успех:Возвращает True
Ошибка:False, если сообщение высылается ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST

Примечания

Отсчёт от 0. Первый символ поля ввода имеет позицию 0.
Если $iStop = -1, то будет выделен весь текст от указанной начальной позиции до последнего символа в поле ввода.

The first character after the last selected character is in the ending position.

Например, чтобы выделить первые четыре символа в поле ввода, используйте начальную позицию 0 и конечную позицию 4.

См. также

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBox_ReplaceEditSel

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $aSel, $hCombo

    ; Создаёт GUI
    GUICreate("Выделяет символы в поле ввода", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Выбирает пункт
    _GUICtrlComboBox_SetCurSel($hCombo, 2)

    ; Выделяет символы в поле ввода
    _GUICtrlComboBox_SetEditSel($hCombo, 0, 4)

    ; Получает позиции выделенного
    $aSel = _GUICtrlComboBox_GetEditSel($hCombo)
    MemoWrite(StringFormat("Позиции выделенного: %d - %d", $aSel[0], $aSel[1]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite