InsertXMLList()

Синтаксис

Result = InsertXMLList(*ParentNode , List() [, *PreviousNode])

Описание

Вставляет указанный Связный список "List()" в качестве нового узла XML в данный родительский узел.

Параметры

*ParentNode	Узел, в который будет вставлен новый дочерний узел. Здесь для вставки нового узла в корень дерева можно использовать функцию RootXMLNode().
List()	Связный список, который будет вставлен в качестве узла в XML.
*PreviousNode (дополн.)	Задаёт дочерний узел узла '*ParentNode', после которого должен быть вставлен новый узел. Если это значение равно 0 или не указано, новый узел вставляется как первый дочерний узел своего родителя. Если это значение равно -1, узел вставляется как последний дочерний узел своего родителя.

Возвращаемое значение

Возвращает указатель на новый узел XML, если он был успешно создан, если же узел в это место вставить не удалось, возвратится ноль.

Комментарии

Правила указанные в CreateXMLNode(), которые определяют, где новый узел может быть вставлен, также применяются к этой функции.

Вставленный узел называется "list", а узлы содержащие элементы - "element". Ниже приведен пример создания XML.

Пример

; В этом примере создается следующее дерево XML:
;
; <list>
;  <element>square</element>
;  <element>circle</element>
;  <element>triangle</element>
; </list>
;
NewList Shapes$()
AddElement(Shapes$()): Shapes$() = "square"
AddElement(Shapes$()): Shapes$() = "circle"
AddElement(Shapes$()): Shapes$() = "triangle"

If CreateXML(0)
    InsertXMLList(RootXMLNode(0), Shapes$())
    FormatXML(0, #PB_XML_ReFormat)
    Debug ComposeXML(0)
EndIf

Пример

; В этом примере создается следующее дерево XML:
;
; <list>
;  <element>
;    <x>100</x>
;    <y>200</y>
;  </element>
;  <element>
;    <x>200</x>
;    <y>400</y>
;  </element>
; </list>
;
Structure Position
    x.l
    y.l
EndStructure

NewList Positions.Position()

For i = 1 To 2
    AddElement(Positions())
    Positions()\x = 100 * i
    Positions()\y = 200 * i
Next i

If CreateXML(0)
    InsertXMLList(RootXMLNode(0), Positions())
    FormatXML(0, #PB_XML_ReFormat)
    Debug ComposeXML(0)
EndIf

См. также

ExtractXMLList(), InsertXMLArray(), InsertXMLMap(), InsertXMLStructure()

Поддерживаемые OS

Все