BeginVectorLayer()

Синтаксис

BeginVectorLayer([Alpha])

Описание

Создаёт новый пустой слой поверх текущей поверхности вывода Векторной графики. С этого момента все операции рисования будут выполняться на этом слое до тех пор, пока не будет вызвана функция EndVectorLayer(). Эта команда также сохраняет текущее состояние свойств Векторной графики, точно так же как это делает SaveVectorState(). Можно создать несколько слоев (по принципу стека) и закрывать их в обратном порядке (последний созданный слой закрывается раньше всех, и тд.).

Параметры

Alpha (дополн.)

Задает прозрачность (Alpha) нового временного слоя. Допустимые значения от 0 (полностью прозрачные) до 255 (полностью НЕпрозрачные). По умолчанию 255.

Возвращаемое значение

Ничего.

Комментарии

Ресурсы, необходимые для создания временного слоя, зависят от размера области отсечения. Поэтому рекомендуется установить отсекающий контур, который охватывает только область, где временный слой будет содержать какой либо рисунок, для экономии ресурсов и улучшения производительности.

Пример

If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))

        ; Полупрозрачный рисунок на базовом слое.
        AddPathCircle(75, 100, 60)
        VectorSourceColor(RGBA(255, 0, 0, 127))
        FillPath()
        AddPathCircle(125, 100, 60)
        VectorSourceColor(RGBA(0, 0, 255, 127))
        FillPath()

        ; Непрозрачный рисунок на полупрозрачном слое.
        BeginVectorLayer(127)
        AddPathCircle(275, 100, 60)
        VectorSourceColor(RGBA(255, 0, 0, 255))
        FillPath()
        AddPathCircle(325, 100, 60)
        VectorSourceColor(RGBA(0, 0, 255, 255))
        FillPath()
        EndVectorLayer()

        StopVectorDrawing()
    EndIf

    Repeat
        Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
EndIf

См. также

EndVectorLayer(), SaveVectorState()

Поддерживаемые OS

Все