MouseButton()

Синтаксис

Result = MouseButton(Button)

Описание

Проверяет, нажата ли указанная кнопка Мыши. Одновременно можно нажимать любое количество кнопок. Перед использованием этой функции необходимо обновить состояние Мыши с помощью команды ExamineMouse().

Параметры

Button

В качестве этого параметра можно использовать одну из следующих констант: #PB_MouseButton_Left : Проверяет, нажата ли левая кнопка мыши #PB_MouseButton_Right : Проверяет, нажата ли правая кнопка мыши #PB_MouseButton_Middle: Проверяет, нажата ли средняя кнопка мыши

Возвращаемое значение

Ненулевое значение, если указанная кнопка мыши нажата, иначе 0.

Пример (фран.)

; Инициализация мира 2D
InitSprite()
InitKeyboard()
InitMouse()

; Открытие окна
OpenWindow(0, 0, 0, 800, 600, "Мышь - MouseButton", #PB_Window_ScreenCentered|#PB_Window_SystemMenu)
OpenWindowedScreen(WindowID(0), 0, 0, 800, 600, 1, 0, 0)

; Управление окнами и экранами
Repeat
    Repeat        ; Управление окнами
        Event  = WindowEvent()
    Until Event = 0

    ExamineMouse() ; Состояние мыши

    ; Просмотр состояния кнопок мыши
    StartDrawing(ScreenOutput())
    DrawText(10, 10, "Нажмите клавишу на клавиатуре, чтобы выйти.", RGB(255, 255, 0))
    DrawText(200, 180, "Нажмите левую, среднюю или правую кнопку мыши.", RGB(255, 0, 0), RGB(255, 255, 0))
    If MouseButton(#PB_MouseButton_Left) <> 0
        DrawText(200, 230, "Левая кнопка", RGB(255, 0, 0), RGB(255, 255, 0))
    Else
        DrawText(200, 230, "Левая кнопка", RGB(255, 255, 255))
    EndIf
    If MouseButton(#PB_MouseButton_Middle) <> 0
        DrawText(350, 230, "Центральная кнопка", RGB(255, 0, 0), RGB(255, 255, 0))
    Else
        DrawText(350, 230, "Центральная кнопка", RGB(255, 255, 255))
    EndIf
    If MouseButton(#PB_MouseButton_Right) <> 0
        DrawText(500, 230, "Правая кнопка", RGB(255, 0, 0), RGB(255, 255, 0))
    Else
        DrawText(500, 230, "Правая кнопка", RGB(255, 255, 255))
    EndIf
    StopDrawing()

    FlipBuffers()
    ClearScreen(RGB(0, 0, 0))

    ExamineKeyboard()
Until KeyboardPushed(#PB_Key_All)
End

См. также

ExamineMouse()

Поддерживаемые OS

Все