GradientColor()

Синтаксис

GradientColor(Position.f , Color)

Описание

Добавляет данный Цвет в данной позиции к спектру градиента цвета.

Параметры

Position.f	Позиция в градиенте для добавления цвета. Этот параметр должен иметь значение от 0,0 до 1.0, с типом float.
Color	Цвет, который будет использоваться для добавки в градиент. Этот цвет может быть в формате RGBA или RGB.

Возвращаемое значение

Ничего.

Комментарии

По умолчанию цвет градиента изменяется в диапазоне от текущего цвета фона в позиции 0.0 до текущего цвета рисования в позиции 1.0. С помощью этой команды можно вставить дополнительные цвета в промежуточные позиции, или переназначить цвета в позициях 0.0 и 1.0.

С помощью команды ResetGradientColors() можно вернуться назад к стандартному градиенту.

Следующие команды могут быть использованы для определения формы градиента:
- LinearGradient()
- CircularGradient()
- EllipticalGradient()
- BoxedGradient()
- ConicalGradient()
- CustomGradient()

Примечание: Эта команда имеет эффект только с поверхностями вывода - ImageOutput() и CanvasOutput(). Градиент влияет на функции рисования только если командой DrawingMode() установлен режим рисования #PB_2DDrawing_Gradient.

Пример

If OpenWindow(0, 0, 0, 400, 200, "2DDrawing Example", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    If CreateImage(0, 400, 200) And StartDrawing(ImageOutput(0))
        Box(0, 0, 400, 200, $FFFFFF)

        DrawingMode(#PB_2DDrawing_Gradient)
        BackColor($0000FF)
        GradientColor(0.4, $00FFFF)
        GradientColor(0.6, $FFFF00)
        FrontColor($FF0000)

        LinearGradient(0, 0, 200, 200)
        Circle(100, 100, 100)
        LinearGradient(350, 100, 250, 100)
        Circle(300, 100, 100)

        StopDrawing()
        ImageGadget(0, 0, 0, 400, 200, ImageID(0))
    EndIf

    Repeat
        Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
EndIf

См. также

ResetGradientColors(), LinearGradient(), CircularGradient(), EllipticalGradient(), BoxedGradient(), ConicalGradient(), CustomGradient(), DrawingMode()

Поддерживаемые OS

Все