Описание функции

SetTabBarGadgetAttribute

Изменяет значение атрибута панели вкладок.

SetTabBarGadgetAttribute(Gadget.i, Attribute.i, Value.i, Overwrite.i=#True)

Параметры

Gadget Идентификатор гаджета.
Attribute Атрибут, комбинация следующих параметров:
    #TabBarGadget_CloseButton - показывает кнопку закрытия на вкладках
    #TabBarGadget_SelectedCloseButton - показывает кнопку закрытия только на выбранной вкладке
    #TabBarGadget_NewTab - добавляет короткую вкладку для создания новой вкладки
    #TabBarGadget_NoTabMoving - запрещает перемещение вкладок
    #TabBarGadget_BottomLine - линия под вкладкими
    #TabBarGadget_MultiLine - вкладки могут распологаться в несколько строк, если не умещаются
    #TabBarGadget_PopupButton - всплывающая кнопка?
    #TabBarGadget_Editable - текст вкладки может редактироваться
    #TabBarGadget_CheckBox - добавляет чекбокс на вкладках
    #TabBarGadget_ReverseOrdering - обратный порядок и правое выравнивание как у еврейских и арабских языков
    #TabBarGadget_MultiSelect - позволяет выбрать несколько вкладок
    #TabBarGadget_TextCutting - позволить обрезанный текст?
    #TabBarGadget_MirroredTabs - отразить вкладки зеркально
    #TabBarGadget_Vertical - вертикальная панель вкладок
    #TabBarGadget_TabRounding - закруглить углы вкладок
    #TabBarGadget_MinTabLength - минимальная длина вкладок в пикселях
    #TabBarGadget_MaxTabLength - максимальная длина вкладок в пикселях
    #TabBarGadget_TabTextAlignment - выравнивание текста
    #TabBarGadget_ScrollPosition -
Value Служит флагом состояния для атрибутов имеющих логической состояние вкл/откл.
Для #TabBarGadget_TabRounding задаёт радиус округления
С флагами мин., макс. длины вкладки задаёт длину в пикселях
Overwrite Перезаписывает атрибут для пунктов. Иначе только для панели вкладок.

См. также

GetTabBarGadgetAttribute, SetTabBarGadgetItemState

Пример

EnableExplicit
; https://www.purebasic.fr/english/viewtopic.php?t=47588
XIncludeFile "TabBarGadget.pbi"
#Window = 0
#Gadget_TabBar = 0
Define i, ww, hw, PnTabHeight, tmp
ww = 420
hw = 200
If OpenWindow(#Window, 0, 0, ww, hw, "TabBarGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    TabBarGadget(#Gadget_TabBar, 0, 0, ww, 26, #TabBarGadget_None, #Window)
    For i = 0 To 5
        AddTabBarGadgetItem(#Gadget_TabBar, i, Str(i))
    Next
    PnTabHeight = GadgetHeight(#Gadget_TabBar) ; предварительный оценочный размер
    ContainerGadget(#PB_Any, 0, PnTabHeight, ww, hw - PnTabHeight, #PB_Container_Flat)
    SetTabBarGadgetAttribute(#Gadget_TabBar, #TabBarGadget_CloseButton, #TabBarGadget_CloseButton)
    SetTabBarGadgetAttribute(#Gadget_TabBar, #TabBarGadget_NewTab, #TabBarGadget_NewTab)
    TabBarGadgetToolTip(#Gadget_TabBar, "Это вкладка", "Создать новую", "Закрыть вкладку")

    Repeat
        Select WaitWindowEvent()
            Case #PB_Event_Gadget
                Select EventGadget()
                    Case #Gadget_TabBar
                        Select EventType()
                            Case #TabBarGadget_EventType_NewItem
                                tmp = CountTabBarGadgetItems(#Gadget_TabBar)
                                AddTabBarGadgetItem(#Gadget_TabBar, #PB_Default, Str(tmp))
                                SetTabBarGadgetState(#Gadget_TabBar, tmp)
                        EndSelect
                EndSelect
            Case #PB_Event_CloseWindow
                CloseWindow(#Window)
                End
        EndSelect
    ForEver
EndIf