Описание функции

NextMTPDirectoryEntry

Получает следующий элемент файловой системы - папку или файл, используется в цикле после вызова ExamineMTPDirectory()

NextMTPDirectoryEntry(ID, @ErrorOutput$)

Параметры

ID Идентификатор подключения
@ErrorOutput$ Указатель на строку содержащую текст ошибки, размером не менее 128 символов включая Null.
Или 0 если нет необходимости получить текстовое описание ошибки в случае ошибки.

Возвращаемое значение

Успех:Возвращает: 1, если операция успешна
Ошибка:Возвращает: 0

См. также

ExamineMTPDirectory, FinishMTPDirectory

Пример

EnableExplicit
; RSBasic
; http://forums.purebasic.com/german/viewtopic.php?t=31465
XIncludeFile "PB.Ex_MTP.pbi"

Global Output$ = Space(1024)
Global ErrorOutput$ = Space(128)
Global DeviceName$

;List all devices to determine the device name.
If ExamineMTP(@ErrorOutput$)
    While NextMTPEntry(@ErrorOutput$)
        MTPEntryName(@Output$, @ErrorOutput$)
        DeviceName$ = Output$
    Wend
EndIf

If OpenMTP(1, DeviceName$, @ErrorOutput$)

    SetMTPDirectory(1, "\Внутренний общий накопитель\DCIM\Camera", @ErrorOutput$)
    If ExamineMTPDirectory(1, @ErrorOutput$)
        While NextMTPDirectoryEntry(1, @ErrorOutput$)
            MTPDirectoryEntryName(1, @Output$, @ErrorOutput$)
            If MTPDirectoryEntryType(1, @ErrorOutput$) = #PBEx_MTP_Type_Directory
                Debug "Folder: " + Output$
            ElseIf MTPDirectoryEntryType(1, @ErrorOutput$) = #PBEx_MTP_Type_File
                Debug "Файл: " + Output$
                Debug "Размер файла: " + Str(MTPDirectoryEntrySize(1, @ErrorOutput$)) + " Байт"
                Debug "Дата создания в секундах: " + MTPDirectoryEntryDate(1, @ErrorOutput$)
                Debug "Дата создания: " + FormatDate("%dd.%mm.%yyyy %hh:%ii:%ss", MTPDirectoryEntryDate(1, @ErrorOutput$))
            EndIf
        Wend
    EndIf

    CloseMTP(1, @ErrorOutput$)
Else
    Debug ErrorOutput$
EndIf

CloseLibrary(PBEx_MTP)