;
; ------------------------------------------------------------
;
;   PureBasic - Font example file
;
;    (c) Fantaisie Software
;
; ------------------------------------------------------------
;
; NOTE: Этот файл не компилируется в демо-версии !
;

LoadFont (0, "Courier", 15)            ; Загрузка шрифта Courrier, размер 15
LoadFont (1, "Arial", 30)              ; Загрузка шрифта Arial, размер 30

If OpenWindow(0, 100, 200, 460, 148, "Font Test") = 0
  MessageRequester("Ошибка", "Не удается открыть окно", 0)
  End
EndIf

If CreateImage(0, 450, 130)

  If StartDrawing(ImageOutput(0))           ;
    Box(0, 0, 450, 130, RGB(255, 255, 255)) ; белый фон
  
    DrawingMode(1)                          ; Прозрачный фон текста
  
    DrawingFont(FontID(0))                 ; Используем шрифт 'Courier'
    DrawText(10,10, "Шрифт: Courier - размер: 15 - Red", RGB(255, 0, 0))  ; Печатаем текст
                
    DrawingFont(FontID(1))                 ; Используем шрифт 'Arial'
    DrawText(10,40, "Шрифт: Arial - размер: 24", RGB(0, 0, 0))      ; Печатаем текст

    StopDrawing()                          ; Это абсолютно необходимо, когда операции рисования  
  EndIf                                    ; закончены !!! Никогда это не забывай !

EndIf

; Отображение изображения в окне
;
ImageGadget(0, 5, 10, 450, 130, ImageID(0))

;
; Это 'цикл событий'. Здесь обрабатываются все действия пользователя.
; Это очень легко понять: когда происходит действие, Событие не  
; равно 0, и мы просто должны увидеть, что произошло ...
;

Repeat

  Event = WaitWindowEvent()
  
Until Event = #PB_Event_CloseWindow    ; Если пользователь нажал на кнопку закрытия

End                                      ; Все открытые окна автоматически закрываются PureBasic