Функция _GraphGDIPlus_Create

         Описание функции

_GraphGDIPlus_Create

Создаёт область графика и подготавливает массив указанных данных

#Include <GraphGDIPlus.au3>
_GraphGDIPlus_Create($hWnd, $iLeft, $iTop, $iWidth, $iHeight [, $hColorBorder = 0xFF000000 [, $hColorFill = 0xFFFFFFFF [, $iSmooth = 2]]])

Параметры

$hWnd Дескриптор GUI
$iLeft Координата левого края графика в GUI
$iTop Координата верхнего края графика в GUI
$iWidth Ширина графика в пикселях
$iHeight Высота графика в пикселях
$hColorBorder [необязательный] Цвет границ прямоугольной области графика (ARGB)
$hColorFill [необязательный] Цвет фона (ARGB)
$iSmooth [необязательный] Сглаживание

Возвращаемое значение

Успех:Возвращает массив, содержащий значения для последующих функций. Массив следующего формата:
[0] - ""
[1] - Дескриптор графического объекта
[2] - Координата левого края
[3] - Координата верхнего края
[4] - Ширина графика
[5] - Высота графика
[6] - x low
[7] - x high
[8] - y low
[9] - y high
[10] - x ticks handles
[11] - x labels handles
[12] - y ticks handles
[13] - y labels handles
[14] - Цвет границ
[15] - Цвет фона
[16] - Дескриптор Bitmap
[17] - Дескриптор Backbuffer
[18] - Последняя использованная X-координата
[19] - Последняя использованная Y-координата
[20] - Дескриптор объекта Карандаш (основного)
[21] - Дескриптор объекта Кисть (fill)
[22] - Дескриптор объекта Карандаш (граница)
[23] - Дескриптор объекта Карандаш (сетка)

Пример

; andybiochem
; http://www.autoitscript.com/forum/index.php?showtopic=104399
#include <GraphGDIPlus.au3>

Local $aGraph, $hGUI, $iMax = 12

$hGUI = GUICreate("Создаёт график", 590, 320)

; Создаёт график
$aGraph = _GraphGDIPlus_Create($hGUI, 40, 20, 530, 260, 0xFF000000, 0xFFCEE3E0)

; Устанавливает шкалу по осям XY
_GraphGDIPlus_Set_RangeX($aGraph, 0, 20, 10, 1, 0) ; мин, макс, деление, цифры ,округление
_GraphGDIPlus_Set_RangeY($aGraph, 0, $iMax, 10, 1, 1)

; Устанавливает сетку по осям XY
_GraphGDIPlus_Set_GridX($aGraph, 1, 0xFF6993BE)
_GraphGDIPlus_Set_GridY($aGraph, $iMax / 10, 0xFF6993BE)

; Рисует график
_GraphGDIPlus_Set_PenColor($aGraph, 0xFF339966) ; Задаёт цвет линии графика
_GraphGDIPlus_Plot_Start($aGraph, 0, 11) ; Задаёт начальную точку
_GraphGDIPlus_Plot_Line($aGraph, 20, 2) ; Задаёт следующую точку

GUISetState()
Do
Until GUIGetMsg() = -3

; Удаляет график, освобождает ресурсы
_GraphGDIPlus_Delete($hGUI, $aGraph)