Функция _GDIPlus_ImageAttributesDispose

         Описание функции

_GDIPlus_ImageAttributesDispose

Освобождает объект ImageAttributes

#Include <GDIP.au3>
_GDIPlus_ImageAttributesDispose($hImageAttributes)

Параметры

$hImageAttributes Указатель на объект ImageAttribute

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

_GDIPlus_ImageAttributesCreate

См. также

Искать GdipDisposeImageAttributes в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIP.au3>
#include <ScreenCapture.au3>

Local $hBitmap, $hBmp, $hGraphics, $hGUI, $hIA, $iDHeight, $iDWidth, $saturation, $tMatrix, $pColorMatrix

_GDIPlus_Startup()

$iDWidth = @DesktopWidth / 3
$iDHeight = @DesktopHeight / 3

$hGUI = GUICreate("Освобождает объект ImageAttributes", $iDWidth, $iDHeight)

$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

; Делает снимок левой верхней части экрана
$hBmp = _ScreenCapture_Capture("", 0, 0, $iDWidth, $iDHeight, False)

; Создаёт объект GDI+ Bitmap из объекта GDI Bitmap
$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp)

$tMatrix = _GDIPlus_ColorMatrixCreateNegative()
$pColorMatrix = DllStructGetPtr($tMatrix)

; Создает объект ImageAttributes
$hIA = _GDIPlus_ImageAttributesCreate()
; Устанавливает матрицу цвета
_GDIPlus_ImageAttributesSetColorMatrix($hIA, 0, True, $pColorMatrix)

GUISetState()

; Рисует изображение в указанном прямоугольнике
_GDIPlus_GraphicsDrawImageRectRectIA($hGraphics, $hBitmap, 0, 0, $iDWidth, $iDHeight, 0, 0, $iDWidth, $iDHeight, $hIA)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_GDIPlus_ImageAttributesDispose($hIA) ; Освобождает объект ImageAttributes
_GDIPlus_ImageDispose($hBitmap)
_GDIPlus_GraphicsDispose($hGraphics)

_GDIPlus_Shutdown()