Функция _GDIPlus_HatchBrushCreate

         Описание функции


_GDIPlus_HatchBrushCreate

Создаёт объект HatchBrush, двухцветный узор

#Include <GDIP.au3>
_GDIPlus_HatchBrushCreate([$iHatchStyle = 0[, $iARGBForeground = 0xFFFFFFFF[, $iARGBBackground = 0xFFFFFFFF]]])

Параметры

$iHatchStyle Стиль, определяющий узор
$iARGBForeground [необязательный] Цвет линий штриховки, в формате ARGB
$iARGBBackground [необязательный] Цвет фона, в формате ARGB

Возвращаемое значение

Успех:Возвращает указатель на новый объект HatchBrush
Ошибка:Возвращает 0, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

Константы узоров объявлены в GDIPConstants.au3, те, которые начинаются с $HatchStyle*
После завершения использования объекта вызовите _GDIPlus_BrushDispose, чтобы освободить ресурсы объекта

См. также

См. также

Искать GdipCreateHatchBrush в библиотеке MSDN

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hBrush, $iX, $iY

    ; Создаёт GUI
    Local $hGUI = GUICreate("Кисть двухцветного узора", 810, 610)
    GUISetState(@SW_SHOW)

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()
    ; Создаёт графический объект из дескриптора окна
    Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    For $i = 0 To 52
        $iX = 10 + Mod($i, 10) * 80
        $iY = 30 + Floor($i / 10) * 100
        _GDIPlus_GraphicsDrawString($hGraphic, $i, $iX, $iY - 16)

        ; Создаёт HatchBrush, используемый в качестве кисти фона для заливки фигуры
        $hBrush = _GDIPlus_HatchBrushCreate($i, 0xFF00FF00, 0xFF0000FF)

        ; Рисует заполненный прямоугольник
        _GDIPlus_GraphicsFillRect($hGraphic, $iX, $iY, 70, 70, $hBrush)

        ; Освобождает ресурсы кисти
        _GDIPlus_BrushDispose($hBrush)
    Next


    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_GraphicsDispose($hGraphic)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc   ;==>Example