Функция _GDIPlus_GraphicsDrawRectangles

_GDIPlus_GraphicsDrawRectangles

Рисует прямоугольники

#Include <GDIP.au3>
_GDIPlus_GraphicsDrawRectangles($hGraphics, $aRects[, $hPen = 0])

Параметры

$hGraphics	Указатель на объект Graphics
$aRects	Массив прямоугольников, которые будут нарисованы: [0][0] - Количество прямоугольников [1][0] - X-координата 1-го прямоугольника [1][1] - Y-координата 1-го прямоугольника [1][2] - Ширина 1-го прямоугольника [1][3] - Высота 1-го прямоугольника ... [n][0] - X-координата n-го прямоугольника [n][1] - Y-координата n-го прямоугольника [n][2] - Ширина n-го прямоугольника [n][3] - Высота n-го прямоугольника
$hPen	[необязательный] Дескриптор объекта карандаша, который используется для рисования замкнутой кривой. Если 0, то сплошная чёрная линия шириной 1 пиксель.

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False, либо:
	Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
	$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
Local $hGUI, $hGraphics, $hPen, $aRects[4][4]

; Инициализирует библиотеку GDI+
_GDIPlus_Startup()

$hGUI = GUICreate("Рисует прямоугольники", 400, 350)
GUISetState()

; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

; Создаёт объект карандаша
$hPen = _GDIPlus_PenCreate(0xFF000000, 3)

; Задаёт прямоугольники
$aRects[0][0] = 3

$aRects[1][0] = 0
$aRects[1][1] = 0
$aRects[1][2] = 100
$aRects[1][3] = 200

$aRects[2][0] = 100
$aRects[2][1] = 200
$aRects[2][2] = 250
$aRects[2][3] = 50

$aRects[3][0] = 300
$aRects[3][1] = 0
$aRects[3][2] = 50
$aRects[3][3] = 100

; Рисует прямоугольники
_GDIPlus_GraphicsDrawRectangles($hGraphics, $aRects, $hPen)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Освобождает ресурсы
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphics)

; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc