_IEImgGetCollection
Возвращает переменную объекта коллекции представляющую теги IMG в документе, или единственное изображение по индексу.
#include <IE.au3>
_IEImgGetCollection(ByRef $o_object [, $i_index = -1])
Параметры
| $o_object | Переменная объекта InternetExplorer.Application, Window, Frame or iFrame object |
| $i_index |
[необязательный] Указывает, что возвращать, коллекцию или экземпляр по индексу 0 или положительное число является индексом возвращаемого экземпляра -1 = (по умолчанию) Возвращает коллекцию |
Возвращаемое значение
| Успех: | Возвращает переменную объекта с коллекцией всех тегов IMG в документе, @extended = img count |
| Ошибка: | Возвращает 0 и устанавливает @error |
| @error: | 0 ($_IEStatus_Success) = Нет ошибок |
| 3 ($_IEStatus_InvalidDataType) = Неверный тип данных | |
| 5 ($_IEStatus_InvalidValue) = Неверное значение | |
| 7 ($_IEStatus_NoMatch) = Нет совпадений | |
| @extended: | Содержит номер неверного параметра |
См. также
_IEFormImageClick, _IEImgClickПример
#include <IE.au3>
; Пример 1 - Открывает страницу AutoIt, получает ссылку на 6-е
; изображения на странице и отображает информацию о нём
; (Примечание: первое изображение с индексом 0)
$oIE = _IECreate("http://www.autoitscript.com/")
$oImg = _IEImgGetCollection($oIE, 5)
$sInfo = "Источник (src): " & $oImg.src & @LF
$sInfo &= "Имя файла: " & $oImg.nameProp & @LF
$sInfo &= "Высота: " & $oImg.height & @LF
$sInfo &= "Ширина: " & $oImg.width & @LF
$sInfo &= "Граница: " & $oImg.border
MsgBox(0, "Информация о 6 изображений", $sInfo)
; Пример 2 - Открывает страницу AutoIt, получает коллекцию Img
; и для каждого отображает src URL
$oIE = _IECreate("http://www.autoitscript.com/")
$oImgs = _IEImgGetCollection($oIE)
$iNumImg = @extended
MsgBox(0, "Информация о коллекции Img", "На этой странице " & $iNumImg & " изображений")
For $oImg In $oImgs
MsgBox(0, "Источник (src) каждого Img", $oImg.src)
Next