_GUICtrlRichEdit_SetScrollPos
Прокручивает содержимое так, чтобы позиция ($iX,$iY) была в левом верхнем углу элемента
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetScrollPos($hWnd, $iX, $iY)
Параметры
| $hWnd | Дескриптор элемента |
| $iX |
X-координата в пикселях |
| $iY |
Y-координата в пикселях |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False и устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
| 102 - $iX не является положительным числом или 0 | |
| 103 - $iY не является положительным числом или 0 |
Примечания
Текст никогда не прокручивается за пределы просматриваемого прямоугольникаСм. также
_GUICtrlRichEdit_GetScrollPosСм. также
Искать EM_SETSCROLLPOS в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_SetText($hRichEdit, "Строка 1")
For $i = 2 To 20
_GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Строка " & $i)
Next
Report("0. Начальная позиция прокрутки, показывающая позицию вставки")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetScrollPos($hRichEdit, 0, 0)
Report("1. Прокручивает к верху")
Case 2
_GUICtrlRichEdit_SetScrollPos($hRichEdit, 7, 22)
Report("2. Прокручивает немного вниз и вправо")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $aPos = _GUICtrlRichEdit_GetScrollPos($hRichEdit)
$sMsg &= @CR & @CR & "Позиция прокрутки " & $aPos[0] & "; " & $aPos[1]
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report