Функция _GUICtrlListView_GetItemTextArray

         Описание функции

_GUICtrlListView_GetItemTextArray

Возвращает текст пункта в массив по колонкам

#include <GuiListView.au3>
_GUICtrlListView_GetItemTextArray($hWnd [, $iItem = -1])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iItem [необязательный] Индекс пункта

Возвращаемое значение

Успех:Возвращает массив следующего формата:
[0] - Количество колонок в массиве (n)
[1] - Текст первой колонки по индексу
[2] - Текст второй колонки по индексу
[n] - Текст последней колонки по индексу
Ошибка:Возвращает массив следующего формата:
[0] - Количество колонок в массиве (0)

Примечания

Если $iItem = -1, то попытка получить текущий выделенный пункт.

См. также

_GUICtrlListView_SetItemText, _GUICtrlListView_GetItemText, _GUICtrlListView_GetItemTextString

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aItem, $sText, $hListView

    GUICreate("Получает текст пунктов в массив", 400, 300)

    $hListView = GUICtrlCreateListView("Колонка 1|Колонка 2|Колонка 3", 2, 2, 394, 268)
    GUICtrlCreateListViewItem("Строка 1|Данные 1|Дополнительно 1", $hListView)
    GUICtrlCreateListViewItem("Строка 2|Данные 2|Дополнительно 2", $hListView)
    GUICtrlCreateListViewItem("Строка 3|Данные 3|Дополнительно 3", $hListView)
    GUICtrlCreateListViewItem("Строка 4|Данные 4|Дополнительно 4", $hListView)
    GUICtrlCreateListViewItem("Строка 5|Данные 5|Дополнительно 5", $hListView)

    GUISetState()

    ; Получает текст 2-го пункта
    $aItem = _GUICtrlListView_GetItemTextArray($hListView, 1)
    For $i = 1 To $aItem[0]
        $sText &= StringFormat("Колонка[%2d] %s", $i, $aItem[$i]) & @LF
    Next

    MsgBox(4160, "Информация", "Текст 2-го пункта (Все колонки): " & @LF & @LF & $sText)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main