Функция _GUICtrlListBox_SetAnchorIndex

         Описание функции

_GUICtrlListBox_SetAnchorIndex

Устанавливает якорный пункт - пункт, с которого начинается множественный выбор

#include <GuiListBox.au3>
_GUICtrlListBox_SetAnchorIndex($hWnd, $iIndex)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListBox_GetAnchorIndex

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $iIndex, $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает якорный пункт", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Устанавливает якорный индекс
    _GUICtrlListBox_SetAnchorIndex($hListBox, 2)

    ; Читает якорный индекс
    $iIndex = _GUICtrlListBox_GetAnchorIndex($hListBox)
    _GUICtrlListBox_SetCurSel($hListBox, $iIndex)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main