Функция _GUICtrlEdit_SetRECTNP

         Описание функции

_GUICtrlEdit_SetRECTNP

Устанавливает позицию прямоугольника многострочного окна редактирования

#include <GuiEdit.au3>
_GUICtrlEdit_SetRECTNP($hWnd, $aRect)

Параметры

$hWnd Дескриптор или идентификатор элемента
$aRect Массив следующего формата:
    [0] - Определяет X -координату левого верхнего угла прямоугольника.
    [1] - Определяет Y -координату левого верхнего угла прямоугольника.
    [2] - Определяет X -координату правого нижнего угла прямоугольника.
    [3] - Определяет Y -координату правого нижнего угла прямоугольника.

Примечания

Функция _GUICtrlEdit_SetRECTNP идентична функции _GUICtrlEdit_SetRECT, отличается только тем, что _GUICtrlEdit_SetRECTNP не перерисовывает окно редактирования.

См. также

_GUICtrlEdit_SetRectNPEx

Пример

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[5] = [1, 85, 180, 285, -1], $aRect

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает прямоугольник", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    GUISetState()

    ; Получает прямоугольник
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; Добавляет текст
    _GUICtrlEdit_AppendText($hEdit, FileRead($sFile))

    ; Устанавливает прямоугольник
    _GUICtrlEdit_SetRECTNP($hEdit, $aRect)

    ; Получает прямоугольник
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Левый: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Верхний: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Правый: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Нижний: " & $aRect[3], 4)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main