Функция TrayItemDelete

         Описание функции

TrayItemDelete

Удаляет элемент меню / пункт из меню в трее.

TrayItemDelete ( controlID )

Параметры

controlID Идентификатор элемента (controlID), возвращаемый функциями TrayCreateItem() или TrayCreateMenu().

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

См. также

TrayCreateItem, TrayCreateMenu

Пример

#NoTrayIcon

Opt("TrayMenuMode", 1 + 2) ; Не отображать в трее пункты меню по умолчанию (Script Paused/Exit) и не отмечать галочками при выборе.

$iDelete = TrayCreateItem("Удалить")
TrayCreateItem("") ; Создаёт разделитель

$iAbout = TrayCreateItem("О программе")
TrayCreateItem("") ; Создаёт разделитель

$iExit = TrayCreateItem("Выход")

TraySetState(1) ; Показывает меню трея

While 1
    Switch TrayGetMsg()
        Case $iAbout
            MsgBox(4096, "", "Пример меню в трее." & @CRLF & @CRLF & _
                    "Версия AutoIt: " & @AutoItVersion & @CRLF & _
                    "Путь установки: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1) - 1))

        Case $iDelete
            ; Отображает диалог с предложением удалить пункт. Если ответ "Да", то возвращается значение 6 и удаление.
            If MsgBox(4, "", "Вы хотите удалить пункт 'Удалить' в меню трея?") = 6 Then
                TrayItemDelete($iDelete) ; Удаляет пункт меню в трее.
            EndIf

        Case $iExit ; Выход
            ExitLoop
    EndSwitch
WEnd